build: cleanup the whole handling of CFLAGS
Simplify --enable parameters in configure, and use a more common default output. Use attributes.m4 from xine/feng instead of a custom piece of code that uses mktemp.
This commit is contained in:
Diego Elio Pettenò
parent
ba8b1ec8be
commit
52c28e2f99
109
configure.ac
109
configure.ac
|
|
@ -64,22 +64,13 @@ AC_ARG_WITH([jdk],
|
|||
])
|
||||
|
||||
AC_ARG_ENABLE([werror],
|
||||
[AS_HELP_STRING([--enable-werror],
|
||||
[set warnings as errors via -Werror (default is no)])],
|
||||
[use_werror=$enableval],
|
||||
[use_werror=no])
|
||||
[AS_HELP_STRING([--enable-werror], [set warnings as errors via -Werror @<:@default=disabled@:>@])])
|
||||
|
||||
AC_ARG_ENABLE([extra-warnings],
|
||||
[AS_HELP_STRING([--enable-extra-warnings],
|
||||
[set extra warnings (default is yes)])],
|
||||
[use_extra_warnings=$enableval],
|
||||
[use_extra_warnings=yes])
|
||||
[AS_HELP_STRING([--disable-extra-warnings], [set extra warnings @<:@default=enabled@:>@])])
|
||||
|
||||
AC_ARG_ENABLE([optimizations],
|
||||
[AS_HELP_STRING([--enable-optimizations],
|
||||
[enable optimizations (default is yes)])],
|
||||
[use_optimizations=$enableval],
|
||||
[use_optimizations=yes])
|
||||
[AS_HELP_STRING([--disable-optimizations], [disable optimizations @<:@default=enabled@:>@])])
|
||||
|
||||
AC_ARG_ENABLE([examples],
|
||||
[AS_HELP_STRING([--enable-examples],
|
||||
|
|
@ -87,12 +78,6 @@ AC_ARG_ENABLE([examples],
|
|||
[use_examples=$enableval],
|
||||
[use_examples=yes])
|
||||
|
||||
AC_ARG_ENABLE([debug],
|
||||
[AS_HELP_STRING([--enable-debug],
|
||||
[enable debugging information (default is yes)])],
|
||||
[use_debug=$enableval],
|
||||
[use_debug=yes])
|
||||
|
||||
AC_ARG_ENABLE([bdjava],
|
||||
[AS_HELP_STRING([--enable-bdjava],
|
||||
[enable BD-Java support (default is no)])],
|
||||
|
|
@ -190,79 +175,26 @@ if test x"$use_bdjava" != x"no"; then
|
|||
fi
|
||||
fi
|
||||
|
||||
dnl function testing for supported compiler options
|
||||
check_cc_options()
|
||||
{
|
||||
local tmpfile=$(mktemp XXXXXXXXXX)
|
||||
local tmpcfile="$tmpfile.c"
|
||||
mv $tmpfile $tmpcfile
|
||||
local retval=1
|
||||
printf "Checking if compiler supports $@... "
|
||||
if $CC -c $@ $tmpcfile -o /dev/null >/dev/null 2>&1; then
|
||||
local retval=0
|
||||
fi
|
||||
rm $tmpcfile
|
||||
if [[ $retval = "0" ]]; then
|
||||
echo "yes"
|
||||
else
|
||||
echo "no"
|
||||
fi
|
||||
return $retval
|
||||
}
|
||||
CC_CHECK_CFLAGS_APPEND([-Wall -Wdisabled-optimization -Wpointer-arith ]dnl
|
||||
[-Wredundant-decls -Wcast-qual -Wwrite-strings -Wtype-limits -Wundef ]dnl
|
||||
[-Wmissing-prototypes -Wshadow])
|
||||
|
||||
dnl set default warnings if supported
|
||||
check_cc_options -Wall && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Wall"
|
||||
check_cc_options -Wdisabled-optimization && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Wdisabled-optimization"
|
||||
check_cc_options -Wpointer-arith && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Wpointer-arith"
|
||||
check_cc_options -Wredundant-decls && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Wredundant-decls"
|
||||
check_cc_options -Wcast-qual && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Wcast-qual"
|
||||
check_cc_options -Wwrite-strings && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Wwrite-strings"
|
||||
check_cc_options -Wtype-limits && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Wtype-limits"
|
||||
check_cc_options -Wundef && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Wundef"
|
||||
check_cc_options -Wmissing-prototypes && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Wmissing-prototypes"
|
||||
check_cc_options -Wshadow && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Wshadow"
|
||||
CC_CHECK_CFLAGS_APPEND([-Werror=implicit-function-declaration ]dnl
|
||||
[-Werror-implicit-function-declaration],
|
||||
[break;])
|
||||
|
||||
dnl no implicit function declarations
|
||||
check_cc_options -Werror-implicit-function-declaration && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Werror-implicit-function-declaration"
|
||||
CC_CHECK_WERROR
|
||||
AS_IF([test "x$enable_werror" = "xyes"], [
|
||||
CFLAGS="${CFLAGS} $cc_cv_werror"
|
||||
])
|
||||
|
||||
dnl use -Werror
|
||||
if [[ $use_werror = "yes" ]]; then
|
||||
check_cc_options -Werror && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Werror"
|
||||
fi
|
||||
AS_IF([test "x$enable_extra_warnings" != "xno"], [
|
||||
CC_CHECK_CFLAGS_APPEND([-Wextra -Winline])
|
||||
])
|
||||
|
||||
dnl use extra warnings
|
||||
if [[ $use_extra_warnings = "yes" ]]; then
|
||||
check_cc_options -Wextra && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Wextra"
|
||||
check_cc_options -Winline && \
|
||||
SET_WARNINGS="$SET_WARNINGS -Winline"
|
||||
fi
|
||||
|
||||
dnl use optimizations
|
||||
if [[ $use_optimizations = "yes" ]]; then
|
||||
check_cc_options -O3 && \
|
||||
SET_OPTIMIZATIONS="$SET_OPTIMIZATIONS -O3"
|
||||
check_cc_options -fomit-frame-pointer && \
|
||||
SET_OPTIMIZATIONS="$SET_OPTIMIZATIONS -fomit-frame-pointer"
|
||||
fi
|
||||
|
||||
dnl use debug
|
||||
if [[ $use_debug = "yes" ]]; then
|
||||
check_cc_options -g && \
|
||||
SET_DEBUG_OPTS="$SET_DEBUG_OPTS -g"
|
||||
fi
|
||||
AS_IF([test "x$enable_optimizations" != "xno"], [
|
||||
CC_CHECK_CFLAGS_APPEND([-O3 -fomit-frame-pointer])
|
||||
])
|
||||
|
||||
dnl use examples
|
||||
AM_CONDITIONAL([USING_EXAMPLES], [ test $use_examples = "yes" ])
|
||||
|
|
@ -322,9 +254,6 @@ AC_SUBST(LT_VERSION_INFO)
|
|||
dnl generate output files
|
||||
AC_SUBST(BDJAVA_CFLAGS)
|
||||
AC_SUBST(DLOPEN_LIBS)
|
||||
AC_SUBST(SET_WARNINGS)
|
||||
AC_SUBST(SET_OPTIMIZATIONS)
|
||||
AC_SUBST(SET_DEBUG_OPTS)
|
||||
AC_CONFIG_FILES([Makefile src/Makefile src/examples/Makefile src/libbluray.pc src/libbluray/bluray-version.h])
|
||||
AC_OUTPUT
|
||||
|
||||
|
|
|
|||
|
|
@ -0,0 +1,296 @@
|
|||
dnl Macros to check the presence of generic (non-typed) symbols.
|
||||
dnl Copyright (c) 2006-2007 Diego Pettenò <flameeyes@gmail.com>
|
||||
dnl Copyright (c) 2006-2007 xine project
|
||||
dnl
|
||||
dnl This program is free software; you can redistribute it and/or modify
|
||||
dnl it under the terms of the GNU General Public License as published by
|
||||
dnl the Free Software Foundation; either version 2, or (at your option)
|
||||
dnl any later version.
|
||||
dnl
|
||||
dnl This program is distributed in the hope that it will be useful,
|
||||
dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||||
dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||||
dnl GNU General Public License for more details.
|
||||
dnl
|
||||
dnl You should have received a copy of the GNU General Public License
|
||||
dnl along with this program; if not, write to the Free Software
|
||||
dnl Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
|
||||
dnl 02110-1301, USA.
|
||||
dnl
|
||||
dnl As a special exception, the copyright owners of the
|
||||
dnl macro gives unlimited permission to copy, distribute and modify the
|
||||
dnl configure scripts that are the output of Autoconf when processing the
|
||||
dnl Macro. You need not follow the terms of the GNU General Public
|
||||
dnl License when using or distributing such scripts, even though portions
|
||||
dnl of the text of the Macro appear in them. The GNU General Public
|
||||
dnl License (GPL) does govern all other use of the material that
|
||||
dnl constitutes the Autoconf Macro.
|
||||
dnl
|
||||
dnl This special exception to the GPL applies to versions of the
|
||||
dnl Autoconf Macro released by this project. When you make and
|
||||
dnl distribute a modified version of the Autoconf Macro, you may extend
|
||||
dnl this special exception to the GPL to apply to your modified version as
|
||||
dnl well.
|
||||
|
||||
dnl Check if the flag is supported by compiler
|
||||
dnl CC_CHECK_CFLAGS_SILENT([FLAG], [ACTION-IF-FOUND],[ACTION-IF-NOT-FOUND])
|
||||
|
||||
AC_DEFUN([CC_CHECK_CFLAGS_SILENT], [
|
||||
AC_CACHE_VAL(AS_TR_SH([cc_cv_cflags_$1]),
|
||||
[ac_save_CFLAGS="$CFLAGS"
|
||||
CFLAGS="$CFLAGS $1"
|
||||
AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
|
||||
[eval "AS_TR_SH([cc_cv_cflags_$1])='yes'"],
|
||||
[eval "AS_TR_SH([cc_cv_cflags_$1])='no'"])
|
||||
CFLAGS="$ac_save_CFLAGS"
|
||||
])
|
||||
|
||||
AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
|
||||
[$2], [$3])
|
||||
])
|
||||
|
||||
dnl Check if the flag is supported by compiler (cacheable)
|
||||
dnl CC_CHECK_CFLAGS([FLAG], [ACTION-IF-FOUND],[ACTION-IF-NOT-FOUND])
|
||||
|
||||
AC_DEFUN([CC_CHECK_CFLAGS], [
|
||||
AC_CACHE_CHECK([if $CC supports $1 flag],
|
||||
AS_TR_SH([cc_cv_cflags_$1]),
|
||||
CC_CHECK_CFLAGS_SILENT([$1]) dnl Don't execute actions here!
|
||||
)
|
||||
|
||||
AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
|
||||
[$2], [$3])
|
||||
])
|
||||
|
||||
dnl CC_CHECK_CFLAG_APPEND(FLAG, [action-if-found], [action-if-not-found])
|
||||
dnl Check for CFLAG and appends them to CFLAGS if supported
|
||||
AC_DEFUN([CC_CHECK_CFLAG_APPEND], [
|
||||
AC_CACHE_CHECK([if $CC supports $1 flag],
|
||||
AS_TR_SH([cc_cv_cflags_$1]),
|
||||
CC_CHECK_CFLAGS_SILENT([$1]) dnl Don't execute actions here!
|
||||
)
|
||||
|
||||
AS_IF([eval test x$]AS_TR_SH([cc_cv_cflags_$1])[ = xyes],
|
||||
[CFLAGS="$CFLAGS $1"; $2], [$3])
|
||||
])
|
||||
|
||||
dnl CC_CHECK_CFLAGS_APPEND([FLAG1 FLAG2], [action-if-found], [action-if-not])
|
||||
AC_DEFUN([CC_CHECK_CFLAGS_APPEND], [
|
||||
for flag in $1; do
|
||||
CC_CHECK_CFLAG_APPEND($flag, [$2], [$3])
|
||||
done
|
||||
])
|
||||
|
||||
dnl Check if the flag is supported by linker (cacheable)
|
||||
dnl CC_CHECK_LDFLAGS([FLAG], [ACTION-IF-FOUND],[ACTION-IF-NOT-FOUND])
|
||||
|
||||
AC_DEFUN([CC_CHECK_LDFLAGS], [
|
||||
AC_CACHE_CHECK([if $CC supports $1 flag],
|
||||
AS_TR_SH([cc_cv_ldflags_$1]),
|
||||
[ac_save_LDFLAGS="$LDFLAGS"
|
||||
LDFLAGS="$LDFLAGS $1"
|
||||
AC_LINK_IFELSE([AC_LANG_SOURCE([int main() { return 1; }])],
|
||||
[eval "AS_TR_SH([cc_cv_ldflags_$1])='yes'"],
|
||||
[eval "AS_TR_SH([cc_cv_ldflags_$1])="])
|
||||
LDFLAGS="$ac_save_LDFLAGS"
|
||||
])
|
||||
|
||||
AS_IF([eval test x$]AS_TR_SH([cc_cv_ldflags_$1])[ = xyes],
|
||||
[$2], [$3])
|
||||
])
|
||||
|
||||
dnl Check for a -Werror flag or equivalent. -Werror is the GCC
|
||||
dnl and ICC flag that tells the compiler to treat all the warnings
|
||||
dnl as fatal. We usually need this option to make sure that some
|
||||
dnl constructs (like attributes) are not simply ignored.
|
||||
dnl
|
||||
dnl Other compilers don't support -Werror per se, but they support
|
||||
dnl an equivalent flag:
|
||||
dnl - Sun Studio compiler supports -errwarn=%all
|
||||
AC_DEFUN([CC_CHECK_WERROR], [
|
||||
AC_CACHE_CHECK(
|
||||
[for $CC way to treat warnings as errors],
|
||||
[cc_cv_werror],
|
||||
[CC_CHECK_CFLAGS_SILENT([-Werror], [cc_cv_werror=-Werror],
|
||||
[CC_CHECK_CFLAGS_SILENT([-errwarn=%all], [cc_cv_werror=-errwarn=%all])])
|
||||
])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_CHECK_ATTRIBUTE], [
|
||||
AC_REQUIRE([CC_CHECK_WERROR])
|
||||
AC_CACHE_CHECK([if $CC supports __attribute__(( ifelse([$2], , [$1], [$2]) ))],
|
||||
AS_TR_SH([cc_cv_attribute_$1]),
|
||||
[ac_save_CFLAGS="$CFLAGS"
|
||||
CFLAGS="$CFLAGS $cc_cv_werror"
|
||||
AC_COMPILE_IFELSE([AC_LANG_SOURCE([$3])],
|
||||
[eval "AS_TR_SH([cc_cv_attribute_$1])='yes'"],
|
||||
[eval "AS_TR_SH([cc_cv_attribute_$1])='no'"])
|
||||
CFLAGS="$ac_save_CFLAGS"
|
||||
])
|
||||
|
||||
AS_IF([eval test x$]AS_TR_SH([cc_cv_attribute_$1])[ = xyes],
|
||||
[AC_DEFINE(
|
||||
AS_TR_CPP([SUPPORT_ATTRIBUTE_$1]), 1,
|
||||
[Define this if the compiler supports __attribute__(( ifelse([$2], , [$1], [$2]) ))]
|
||||
)
|
||||
$4],
|
||||
[$5])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_CONSTRUCTOR], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[constructor],,
|
||||
[extern void foo();
|
||||
void __attribute__((constructor)) ctor() { foo(); }],
|
||||
[$1], [$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_DESTRUCTOR], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[destructor],,
|
||||
[extern void foo();
|
||||
void __attribute__((destructor)) dtor() { foo(); }],
|
||||
[$1], [$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_FORMAT], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[format], [format(printf, n, n)],
|
||||
[void __attribute__((format(printf, 1, 2))) printflike(const char *fmt, ...) { fmt = (void *)0; }],
|
||||
[$1], [$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_FORMAT_ARG], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[format_arg], [format_arg(printf)],
|
||||
[char *__attribute__((format_arg(1))) gettextlike(const char *fmt) { fmt = (void *)0; }],
|
||||
[$1], [$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_VISIBILITY], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[visibility_$1], [visibility("$1")],
|
||||
[void __attribute__((visibility("$1"))) $1_function() { }],
|
||||
[$2], [$3])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_NONNULL], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[nonnull], [nonnull()],
|
||||
[void __attribute__((nonnull())) some_function(void *foo, void *bar) { foo = (void*)0; bar = (void*)0; }],
|
||||
[$1], [$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_UNUSED], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[unused], ,
|
||||
[void some_function(void *foo, __attribute__((unused)) void *bar);],
|
||||
[$1], [$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_SENTINEL], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[sentinel], ,
|
||||
[void some_function(void *foo, ...) __attribute__((sentinel));],
|
||||
[$1], [$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_DEPRECATED], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[deprecated], ,
|
||||
[void some_function(void *foo, ...) __attribute__((deprecated));],
|
||||
[$1], [$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_ALIAS], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[alias], [weak, alias],
|
||||
[void other_function(void *foo) { }
|
||||
void some_function(void *foo) __attribute__((weak, alias("other_function")));],
|
||||
[$1], [$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_MALLOC], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[malloc], ,
|
||||
[void * __attribute__((malloc)) my_alloc(int n);],
|
||||
[$1], [$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_PACKED], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[packed], ,
|
||||
[struct astructure { char a; int b; long c; void *d; } __attribute__((packed));
|
||||
char assert@<:@(sizeof(struct astructure) == (sizeof(char)+sizeof(int)+sizeof(long)+sizeof(void*)))-1@:>@;],
|
||||
[$1], [$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_CONST], [
|
||||
CC_CHECK_ATTRIBUTE(
|
||||
[const], ,
|
||||
[int __attribute__((const)) twopow(int n) { return 1 << n; } ],
|
||||
[$1], [$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_FLAG_VISIBILITY], [
|
||||
AC_REQUIRE([CC_CHECK_WERROR])
|
||||
AC_CACHE_CHECK([if $CC supports -fvisibility=hidden],
|
||||
[cc_cv_flag_visibility],
|
||||
[cc_flag_visibility_save_CFLAGS="$CFLAGS"
|
||||
CFLAGS="$CFLAGS $cc_cv_werror"
|
||||
CC_CHECK_CFLAGS_SILENT([-fvisibility=hidden],
|
||||
cc_cv_flag_visibility='yes',
|
||||
cc_cv_flag_visibility='no')
|
||||
CFLAGS="$cc_flag_visibility_save_CFLAGS"])
|
||||
|
||||
AS_IF([test "x$cc_cv_flag_visibility" = "xyes"],
|
||||
[AC_DEFINE([SUPPORT_FLAG_VISIBILITY], 1,
|
||||
[Define this if the compiler supports the -fvisibility flag])
|
||||
$1],
|
||||
[$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_FUNC_EXPECT], [
|
||||
AC_REQUIRE([CC_CHECK_WERROR])
|
||||
AC_CACHE_CHECK([if compiler has __builtin_expect function],
|
||||
[cc_cv_func_expect],
|
||||
[ac_save_CFLAGS="$CFLAGS"
|
||||
CFLAGS="$CFLAGS $cc_cv_werror"
|
||||
AC_COMPILE_IFELSE(
|
||||
[int some_function() {
|
||||
int a = 3;
|
||||
return (int)__builtin_expect(a, 3);
|
||||
}],
|
||||
[cc_cv_func_expect=yes],
|
||||
[cc_cv_func_expect=no])
|
||||
CFLAGS="$ac_save_CFLAGS"
|
||||
])
|
||||
|
||||
AS_IF([test "x$cc_cv_func_expect" = "xyes"],
|
||||
[AC_DEFINE([SUPPORT__BUILTIN_EXPECT], 1,
|
||||
[Define this if the compiler supports __builtin_expect() function])
|
||||
$1],
|
||||
[$2])
|
||||
])
|
||||
|
||||
AC_DEFUN([CC_ATTRIBUTE_ALIGNED], [
|
||||
AC_REQUIRE([CC_CHECK_WERROR])
|
||||
AC_CACHE_CHECK([highest __attribute__ ((aligned ())) supported],
|
||||
[cc_cv_attribute_aligned],
|
||||
[ac_save_CFLAGS="$CFLAGS"
|
||||
CFLAGS="$CFLAGS $cc_cv_werror"
|
||||
for cc_attribute_align_try in 64 32 16 8 4 2; do
|
||||
AC_COMPILE_IFELSE([
|
||||
int main() {
|
||||
static char c __attribute__ ((aligned($cc_attribute_align_try))) = 0;
|
||||
return c;
|
||||
}], [cc_cv_attribute_aligned=$cc_attribute_align_try; break])
|
||||
done
|
||||
CFLAGS="$ac_save_CFLAGS"
|
||||
])
|
||||
|
||||
if test "x$cc_cv_attribute_aligned" != "x"; then
|
||||
AC_DEFINE_UNQUOTED([ATTRIBUTE_ALIGNED_MAX], [$cc_cv_attribute_aligned],
|
||||
[Define the highest alignment supported])
|
||||
fi
|
||||
])
|
||||
|
|
@ -3,14 +3,9 @@ LIB_VERSION_INFO="@LT_VERSION_INFO@"
|
|||
SUBDIRS= . examples
|
||||
|
||||
SET_FEATURES = -D_ISOC99_SOURCE -D_POSIX_C_SOURCE=200112L -D_REENTRANT
|
||||
SET_WARNINGS = @SET_WARNINGS@
|
||||
SET_OPTIMIZATIONS = @SET_OPTIMIZATIONS@
|
||||
SET_DEBUG_OPTS = @SET_DEBUG_OPTS@
|
||||
SET_INCLUDES = -I$(top_srcdir) -Ifile -Ilibbluray/bdnav
|
||||
|
||||
AM_CFLAGS = -std=c99 $(SET_FEATURES) $(SET_WARNINGS) $(SET_OPTIMIZATIONS) \
|
||||
$(SET_DEBUG_OPTS) $(SET_INCLUDES) $(LIBXML2_CFLAGS) $(FT2_CFLAGS)
|
||||
CFLAGS=$(shell test -z "$$CFLAGS" || echo "$$CFLAGS")
|
||||
AM_CFLAGS = -std=c99 $(SET_FEATURES) $(SET_INCLUDES) $(LIBXML2_CFLAGS) $(FT2_CFLAGS)
|
||||
|
||||
SOURCES_bdj = libbluray/bdj/bdj.h \
|
||||
libbluray/bdj/bdj_private.h \
|
||||
|
|
|
|||
|
|
@ -1,12 +1,7 @@
|
|||
SET_FEATURES = -D_ISOC99_SOURCE -D_POSIX_C_SOURCE=200112L -D_REENTRANT
|
||||
SET_WARNINGS = @SET_WARNINGS@
|
||||
SET_OPTIMIZATIONS = @SET_OPTIMIZATIONS@
|
||||
SET_DEBUG_OPTS = @SET_DEBUG_OPTS@
|
||||
SET_INCLUDES = -I$(top_srcdir) -I$(top_srcdir)/src -I$(top_srcdir)/src/file -I$(top_srcdir)/src/libbluray/bdnav
|
||||
|
||||
AM_CFLAGS = -std=c99 $(SET_FEATURES) $(SET_WARNINGS) $(SET_OPTIMIZATIONS) \
|
||||
$(SET_DEBUG_OPTS) $(SET_INCLUDES)
|
||||
CFLAGS=$(shell test -z "$$CFLAGS" || echo "$$CFLAGS")
|
||||
AM_CFLAGS = -std=c99 $(SET_FEATURES) $(SET_INCLUDES)
|
||||
|
||||
if USING_EXAMPLES
|
||||
|
||||
|
|
|
|||
Loading…
Reference in New Issue